
Guide/Readme

TypeCheck: Fast and flexible runtime type-checking for your Elixir projects.

  Core ideas


	Type- and function specifications are constructed using (essentially) the same syntax as built-in Elixir Typespecs.
	When a value does not match a type check, the user is shown human-friendly error messages.
	Types and type-checks are generated at compiletime.	This means type-checking code is optimized rigorously by the compiler.


	Property-checking generators can be extracted from type specifications without extra work.	Automatically create a spectest which checks for each function if it adheres to its spec.


	Flexibility to add custom checks: Subparts of a type can be named, and 'type guards' can be specified to restrict what values are allowed to match that refer to these types.

Prefer to watch a presentation instead of reading? See "TypeCheck: Effortless Runtime Type Checking" - Marten Wijnja - ElixirConf EU 2022.

  
    
  
  Usage Example


We add use TypeCheck to a module 
and wherever we want to add runtime type-checks 
we replace the normal calls to @type and @spec with @type! and @spec! respectively.
defmodule User do
  use TypeCheck
  defstruct [:name, :age]

  @type! t :: %User{name: binary, age: integer}
end

defmodule AgeCheck do
  use TypeCheck

  @spec! user_older_than?(User.t, integer) :: boolean
  def user_older_than?(user, age) do
    user.age >= age
  end
end
Now we can try the following:
iex> AgeCheck.user_older_than?(%User{name: "Qqwy", age: 11}, 10)
true
iex> AgeCheck.user_older_than?(%User{name: "Qqwy", age: 9}, 10)
false
So far so good. Now let's see what happens when we pass values that are incorrect:
iex> AgeCheck.user_older_than?("foobar", 42)
** (TypeCheck.TypeError) At lib/type_check_example.ex:28:
The call to `user_older_than?/2` failed,
because parameter no. 1 does not adhere to the spec `%User{age: integer(), name: binary()}`.
Rather, its value is: `"foobar"`.
Details:
  The call `user_older_than?("foobar", 42)` 
  does not adhere to spec `user_older_than?(%User{age: integer(), name: binary()},  integer()) :: boolean()`. Reason:
    parameter no. 1:
      `"foobar"` does not check against `%User{age: integer(), name: binary()}`. Reason:
        `"foobar"` is not a map.
    (type_check_example 0.1.0) lib/type_check_example.ex:28: AgeCheck.user_older_than?/2
iex> AgeCheck.user_older_than?(%User{name: nil, age: 11}, 10)
** (TypeCheck.TypeError) At lib/type_check_example.ex:28:
The call to `user_older_than?/2` failed,
because parameter no. 1 does not adhere to the spec `%User{age: integer(), name: binary()}`.
Rather, its value is: `%User{age: 11, name: nil}`.
Details:
  The call `user_older_than?(%User{age: 11, name: nil}, 10)` 
  does not adhere to spec `user_older_than?(%User{age: integer(), name: binary()},  integer()) :: boolean()`. Reason:
    parameter no. 1:
      `%User{age: 11, name: nil}` does not check against `%User{age: integer(), name: binary()}`. Reason:
        under key `:name`:
          `nil` is not a binary.
    (type_check_example 0.1.0) lib/type_check_example.ex:28: AgeCheck.user_older_than?/2
iex> AgeCheck.user_older_than?(%User{name: "Aaron", age: nil}, 10) 
** (TypeCheck.TypeError) At lib/type_check_example.ex:28:
The call to `user_older_than?/2` failed,
because parameter no. 1 does not adhere to the spec `%User{age: integer(), name: binary()}`.
Rather, its value is: `%User{age: nil, name: "Aaron"}`.
Details:
  The call `user_older_than?(%User{age: nil, name: "Aaron"}, 10)` 
  does not adhere to spec `user_older_than?(%User{age: integer(), name: binary()},  integer()) :: boolean()`. Reason:
    parameter no. 1:
      `%User{age: nil, name: "Aaron"}` does not check against `%User{age: integer(), name: binary()}`. Reason:
        under key `:age`:
          `nil` is not an integer.
    (type_check_example 0.1.0) lib/type_check_example.ex:28: AgeCheck.user_older_than?/2
    
iex> AgeCheck.user_older_than?(%User{name: "José", age: 11}, 10.0) 
** (TypeCheck.TypeError) At lib/type_check_example.ex:28:
The call to `user_older_than?/2` failed,
because parameter no. 2 does not adhere to the spec `integer()`.
Rather, its value is: `10.0`.
Details:
  The call `user_older_than?(%User{age: 11, name: "José"}, 10.0)` 
  does not adhere to spec `user_older_than?(%User{age: integer(), name: binary()},  integer()) :: boolean()`. Reason:
    parameter no. 2:
      `10.0` is not an integer.
    (type_check_example 0.1.0) lib/type_check_example.ex:28: AgeCheck.user_older_than?/2
And if we were to introduce an error in the function definition:
defmodule AgeCheck do
  use TypeCheck

  @spec! user_older_than?(User.t, integer) :: boolean
  def user_older_than?(user, age) do
    user.age
  end
end
Then we get a nice error message explaining that problem as well:
** (TypeCheck.TypeError) The call to `user_older_than?/2` failed,
because the returned result does not adhere to the spec `boolean()`.
Rather, its value is: `26`.
Details:
  The result of calling `user_older_than?(%User{age: 26, name: "Marten"}, 10)` 
  does not adhere to spec `user_older_than?(%User{age: integer(), name: binary()},  integer()) :: boolean()`. Reason:
    Returned result:
      `26` is not a boolean.
    (type_check_example 0.1.0) lib/type_check_example.ex:28: AgeCheck.user_older_than?/2

  
    
  
  Features & Roadmap



  
    
  
  Implemented


	[x] Proof and implementation of the basic concept
	[x] Custom type definitions (type, typep, opaque)	[x] Basic
	[x] Parameterized


	[x] Hide implementation of opaque from documentation
	[x] Spec argument types checking
	[x] Spec return type checking
	[x] Spec possibly named arguments
	[x] Implementation of Elixir's builtin types	[x] Primitive types
	[x] More primitive types
	[x] Compound types
	[x] special forms like |, a..b etc.
	[x] Literal lists
	[x] Maps with keys => types
	[x] Structs with keys => types
	[x] More map/list-based structures.
	[x] Bitstring type syntax (<<>>, <<_ :: size>>, <<_ :: _ * unit>>, <<_ :: size, _ :: _ * unit>>)


	[x] A when to add guards to typedefs for more power.
	[x] Make errors raised when types do not match humanly readable	[x] Improve readability of spec-errors by repeating spec and which parameter did not match.


	[x] Creating generators from types
	[x] Don't warn on zero-arity types used without parentheses.
	[x] Hide structure of opaque and typep from documentation
	[x] Make sure to handle recursive (and mutually recursive) types without hanging.	[x] A compile-error is raised when a type is expanded more than a million times
	[x] A macro called lazy is introduced to allow to defer type expansion to runtime (to within the check).


	[x] the Elixir formatter likes the way types+specs are constructed
	[x] A type impl(ProtocolName) to work with 'any type implementing protocol Protocolname'.	[x] Type checks.
	[x] StreamData generator.


	[x] High code-coverage to ensure stability of implementation.
	[x] Make sure we handle most (if not all) of Typespec's primitive types and syntax. (With the exception of functions and binary pattern matching)
	[x] Option to turn @type/@opaque/@typep-injection off for the cases in which it generates improper results.
	[x] Manually overriding generators for user-specified types if so desired.
	[x] Creating generators from specs	[x] Wrap spec-generators so you have a single statement to call in the test suite which will prop-test your function against all allowed inputs/outputs.


	[x] Option to turn the generation of runtime checks off for a given module in a particular environment (enable_runtime_checks).
	[x] Support for function-types (for typechecks as well as property-testing generators):	(-> result_type)
	(...-> result_type)
	(param_type, param2_type -> result_type)


	[x] Basic support for maps with a single required(type) or optional(type).
	[x] Overrides for builtin remote types (String.t,Enum.t, Range.t, MapSet.t etc.) (75% done) Details
	[x] Overrides for more builtin remote types
	[x] Support for maps with mixed required(type) and optional(type) syntaxes.
	[x] Configurable setting to turn checks on/off at compile-time, on a per-OTP-app basis (so you have control over your dependencies) as well as your individual modules.
	[x] Hide named types from opaque types.
	[x] A way to define structs and their field types at the same time.
	[x] Finalize formatter specification and make a generator for this so that people can easily test their own formatters.


  
    
  
  Pre-stable



  
    
  
  Longer-term future ideas


	[ ] Per-module or even per-spec settings to turn on/off, configure formatter, etc.


  
    
  
  Installation


TypeCheck is available in Hex. The package can be installed
by adding type_check to your list of dependencies in mix.exs:
def deps do
  [
    {:type_check, "~> 0.13.3"},
    # To allow spectesting and property-testing data generators (optional):
    {:stream_data, "~> 0.5.0", only: :test}, 
  ]
end
The documentation can be found at https://hexdocs.pm/type_check.

  
    
  
  Formatter


TypeCheck exports a couple of macros that you might want to use without parentheses. To make mix format respect this setting, add import_deps: [:type_check] to your .formatter.exs file.

  
    
  
  Changelog


The full changelog can be found here

  
    
  
  TypeCheck compared to other tools


TypeCheck is by no means the other solution out there to reduce the number of bugs in your code.

  
    
  
  Elixir's builtin typespecs and Dialyzer


Elixir's builtin type-specifications use the same syntax as TypeCheck.
They are however not used by the compiler or the runtime, and therefore mainly exist to improve your documentation.
Besides documentation, extra external tools like Dialyzer can be used to perform static analysis of the types used in your application.
Dialyzer is an opt-in static analysis tool. This means that it can point out some inconsistencies or bugs, but because of its opt-in nature, there are also many problems it cannot detect, and it requires your dependencies to have written all of their typespecs correctly.
Dialyzer is also (unfortunately) infamous for its at times difficult-to-understand error messages.
An advantage that Dialyzer has over TypeCheck is that its checking is done without having to execute your program code (thus not having any effect on the runtime behaviour or efficiency of your projects).
Because TypeCheck adds @type, @typep, @opaque and @spec-attributes based on the types that are defined, it is possible to use Dialyzer together with TypeCheck.

  
    
  
  Norm


Norm is an Elixir library for specifying the structure of data that can be used for both validation and data-generation.
On a superficial level, Norm and TypeCheck seem similar. However, there are important differences in their design considerations.

  
    
  
  Is it any good?


yes

  Changelog


	0.13.7 -
	Fixes: (c.f. #195)	Fixing new compiler warnings (stricter checks, deprecation warnings) of Elixir v1.16/v1.17
	Ensuring map order shown in most output is sorted, esp. when creating fixed_map/1s (including structs). This ensures output of inspect(my_type) and type error formatting should be identical between OTP <= 25 and OTP 26+




	0.13.6 -
	Support for Elixir v1.17.x:	Fix an oversight in the pre-expander now that there was a slight change to the Elixir AST format. Thank you, @skwerlman! (c.f. #190)
	Fixing a bunch of compile-time warnings. Amongst them, a reordering of split function heads (Thank you, @ulfurinn! c.f. #191)


	Fixing some documentation typos, Thank you, @kianmeng! (c.f. #179)


	0.13.5 -
	Support for Elixir v1.15.x. Thank you so much for your guidance and help, @josevalim!  (c.f. #185, #186)	This required turning off part of TypeCheck's self-usage ('dogfooding'). This change should be temporary and will be re-introduced in a future version (c.f. #187).




	0.13.4 -
	No code changes, but two small improvements to the documentation:	Changelog has been split off from the README file.
	A link to Marten's ElixirConf EU 2022 talk about TypeCheck has been added.




	0.13.3 -
	Fixes:	Ensures that TypeCheck can be used in Erlang-style modules (that do not start with 'Elixir.') (c.f. #174).




	0.13.2 -
	Fixes:	Fixes issue when unions are used as type arguments in remote types. Than you very much, @dvic! (c.f. #164).




	0.13.1 -
	Fixes:	Fixes issues with aliases to remote types not being followed. (c.f. #160)




	0.13.0 - 
	Additions:	Support for maps with multiple optional atom keys. Thank you very much, @dvic! (c.f. #165)


	Fixes:	Fixes 'Enumerable not implemented' crash when passing a struct to a type expecting a fixed map. (c.f. #161)




	0.12.4 - 
	Fixes:	Allow syntax %{String.t() => any()} as shorthand for %{required(String.t()) => any()}. (c.f. #152)
	Situations in which the fully qualified name of a type defined in the current module were not picked up (Example.t() not being found inside specs in Example. even though Example defined a type called t()). (c.f. #154)
	A problem with using types with type guards in other modules. (c.f. #147)




	0.12.3 -
	Fixes:	Compatibility problems with Elixir v1.14. (Code.Identifier.inspect_as_key, working with the AST of imported functions)  Thank you very much, @marcandre! (c.f. #150)




	0.12.2 -
	Fixes:	Compilation error in a new Phoenix 1.16 project. Thank you very much, @assimelha! (c.f. #114)




	0.12.1 - 
	Performance:	Significant reduction on generated code size of runtime type checks. This will speed up compilation roughly ~10-50%.


	Fixes:	No longer use white ANSI color in exception formatting, ensuring messages of the DefaultFormatter are also visible on white backgrounds (Livebook, anyone? :D)
	Skip OTP app lookup (used to fetch per OTP app compile-time configuration) if we're not compiled inside an OTP app (such as inside a Livebook).
	Improve generator for Regex.t() to generate only correct regular expressions. Thank you very much, @skwerlman!(c.f. #133)




	0.12.0 - 
	Additions:	The default options used are now fetched from the application configuration. This means that you can configure a default for your app as well as for each of your dependencies(!) by adding config :app_name, :type_check [...] to your configuration file(s). (c.f. #61)
	TypeCheck.External module, with functions to work with typespecs in modules outside of your control. Thank you very much, @orsinium! (c.f. #113)	fetch_spec to build a TypeCheck type from any function that has a @spec.
	fetch_type to build a TypeCheck type from any @type.
	enforce_spec! to wrap a call to any function that has a @spec with a runtime type-check on the input parameters and return value.
	apply and apply! to wrap a call to any function with the function spec type that you give it.


	TypeCheck.Defstruct.defstruct!, a way to combine defstruct, @enforce_keys and the creation of the struct's type, reducing boilerplate and the possibility of mistakes. (c.f. #118)


	Fixes:	Long-standing issue where Dialyzer would sometimes complain in apps using TypeCheck is resolved. (c.f. #95)
	Creation of the new maybe_nonempty_list type will no longer get stuck in an infinite loop on creation. (c.f. #120)




	0.11.0 - 
	Additions:	Support for fancier map syntaxes:	%{required(key_type) => value_type} Maps with a single kind of required key-value type.
	%{optional(key_type) => value_type} Maps with a single kind of optional key-value type.
	%{:some => a(), :fixed => b(), :keys => c(), optional(atom()) => any()} Maps with any number of fixed keys and a single optional key-value type.
	TypeCheck now supports nearly all kinds of map types that see use. Archaic combinations of optional and required are not supported, but also not very useful types in practice.
	Because of this, the inspection of the builtin type map(key, value) has been changed to look the same as an optional map. This is a minor backwards-incompatible change.


	Desugaring %{} has changed from 'any map' to 'the empty map' in line with Elixir's Typespecs. This is a minor backwards-incompatible change.
	Support for the builtin types port(), reference() and (based on these) identifier().
	Support for the builtin type struct().
	Support for the builtin type timeout().
	Support for the builtin type nonempty_charlist() and maybe_improper_list and (based on these) iolist() and iodata().
	Adding types depending on these builtins to the default type overrides. We now support all modules of the full standard library!
	TypeCheck.Credo.Check.Readability.Specs: an opt-in alternative Credo check which will check whether all functions have either a @spec! or 'normal' @spec. (Fixes #102).




	0.10.8 - 
	Fixes:	Ensures that the Inspect protocol is properly implemented for sized bitstring types (c.f. #104). Thank you very much, @trarbr!




	0.10.7 - 
	Fixes:	Ensures fixed-maps are checked for superfluous keys (c.f. #96). Thank you very much, @spatrik!




	0.10.6 - 
	Fixes:	Fixes issue where Dialyzer would sometimes complain about the generated return-type checking code if the implementation of the function itself was trivial. (c.f. #85).




	0.10.5 - 
	Additions:	Support for the builtin types of the System module. Thank you, @paulswartz!




	0.10.4 -
	Fixes:	Fixes issue where sometimes results of specs returning a struct would remove some or all struct fields. (c.f. #78)
	Related: Ensures that when a @type! containing a %__MODULE__{} is used before that module's defstruct, a clear CompileError is created (c.f. #83).




	0.10.3 - 
	Fixes:	Fixes issue when TypeCheck specs were used inside a defprotocol module or other modules where the normal def/defp macros are hidden/overridden.




	0.10.2 - 
	Fixes:	Fixes issue where FixedMaps would accept maps any maps (even those missing the required keys) sometimes. (c.f. #74)




	0.10.1 - 
	Fixes:	Swaps Murmur out for Erlang's builtin :erlang.phash2/2 to generate data for function-types, allowing the removal of the optional dependency on the :murmur library.




	0.10.0 -
	Additions	Support for function-types (for typechecks as well as property-testing generators):	(-> result_type)
	(...-> result_type)
	(param_type, param2_type -> result_type)




	Fixes:	Wrapping private functions no longer make the function public. (c.f. #64)
	Wrapping macros now works correctly. (also related to #64)
	Using __MODULE__ inside a struct inside a type now expands correctly. (c.f. #66)




	0.9.0 - 
	Support for bitstring type syntax: <<>>, <<_ :: size>>, <<_ :: _ * unit>>, <<_ :: size, _ :: _ * unit>> (both as types and as generators)


	0.8.2 - 
	Fixed compiler warnings when optional dependency StreamData is not installed.
	Fixed pretty-printing of typedoc of opaque types.


	0.8.1 - 
	Improved documentation with a page comparing TypeCheck with Elixir's plain typespecs. (Thank you very much, @baldwindavid )
	Addition of missing override for the type t Range.t/0. (Thank you very much, @baldwindavid )


	0.8.0 -
	Fixes prettyprinting of TypeCheck.Builtin.Range.
	Addition of require TypeCheck.Type to use TypeCheck so there no longer is a need to call this manually if you want to e.g. use TypeCheck.Type.build/1.
	Pretty-printing of types and TypeError output in multiple colors.
	Nicer indentation of errors.
	named types are now printed in abbreviated fashion if they are repeated multiple times in an error message. This makes a nested error message much easier to read, especially for larger specs.
	[type] no longer creates a fixed_list(type) but instead a list(type) (just as Elixir's own typespecs.)
	Support for [...] and [type, ...]as alias for nonempty_list() and nonempty_list(type) respectively.
	Remove support for list literals with multiple elements.
	Improved documentation. Thank you, @0ourobor0s!


	0.7.0 - Addition of the option enable_runtime_checks. When false, all runtime checks in the given module are completely disabled.
	Adding DateTime.t to the default overrides, as it was still missing.


	0.6.0 - Addition of spectest & 'default overrides' Elixir's standard library types:
	Adding TypeCheck.ExUnit, with the function spectest to test function-specifications.	Possibility to use options :except, :only, :initial_seed.
	Possibility to pass custom options to StreamData.


	Adding TypeCheck.DefaultOverrides with many sub-modules containing checked typespecs for the types in Elixir's standard library (75% done).	Ensure that these types are correct also on older Elixir versions (1.9, 1.10, 1.11)


	By default load these 'DefaultOverrides', but have the option to turn this behaviour off in TypeCheck.Option. 
	Nice generators for Enum.t, Collectable.t, String.t.
	Support for the builtin types:	pid()
	nonempty_list(), nonempty_list(type).


	Allow use TypeCheck in IEx or other non-module contexts, to require TypeCheck and import TypeCheck.Builtin in the current scope (without importing/using the macros that only work at the module level.)
	The introspection function __type_check__/1 is now added to any module that contains a use TypeCheck.
	Fixes the Inspect implementation of custom structs, by falling back to Any, which is more useful than attempting to use a customized implementation that would try to read the values in the struct and failing because the struct-type containing types in the fields.
	Fixes conditional compilation warnings when optional dependency :stream_data was not included in your project.


	0.5.0 - Stability improvements:
	Adding Typecheck.Option debug: true, which will (at compile-time) print the checks that TypeCheck is generating.
	Actually autogenerate a @spec, which did not yet happen before.
	When writing @autogen_typespec false, no typespec is exported for the next @type!/@opaque/@spec! encountered in a module.
	Code coverage increased to 85%
	Bugfixes w.r.t. generating typespecs
	Fixes compiler-warnings on unused named types when using a type guard. (c.f. #25)
	Fixes any warnings that were triggered during the test suite before.


	0.4.0 - Support for impl(ProtocolName) to accept any type implementing a particular protocol.
	Also adds rudimentary support for overriding remote types.
	Bugfix when inspecting lazy( ...)-types.


	0.3.2 - Support for unquote fragments inside types and specs. (c.f. #39)

	0.3.1 - Fixed link in the documentation.

	0.3.0 - Improve DefaultFormatter output when used with long function- or type-signatures (c.f. #32). Also, bugfix for Builtin.tuple/1.

	0.2.3 - Bugfix release: Ensure TypeCheck compiles on Elixir v1.11 (#30), Ensure StreamData truly is an optional dependency (#27).

	0.2.2 - Support for literal strings should no longer break in Elixir's builtin typespecs.

	0.2.1 - Improved parsing of types that have a type-guard at the root level. (c.f. #24), support for custom generators.

	0.2.0 - Improved (and changed) API that works better with the Elixir formatter: Use @type!/@spec! instead, support named types in specs.

	0.1.2 - Added missing keyword type to TypeCheck.Builtin (#20)

	0.1.1 - Fixing some documentation typos

	0.1.0 - Initial Release




  

    
Introducing TypeCheck

Type-checking and spec-testing with TypeCheck
TypeCheck is an elixir library to, you guessed it, check the types of the values, variables and functions in your Elixir projects.
Elixir is a strong, dynamically typed programming language.
'Strong' (as opposed to 'weak') means that when we try to perform an unsupported operation on a value (like 'multiplying strings'), we get an error, rather than silent faulty behaviour.
'Dynamic' (as opposed to 'Static') means that which operations we do with our values is not checked at compile-time, but only once the program itself is running.
However, when such a failure happens at runtime, the resulting error (and more importantly: what the cause was of an error) is not always very clear.
Is it a bug in your code? Or a bug in a library you are using?
Where in the deeply nested tree of structs is the problem that results in a ** (BadFunctionError) expected a function, got: nil somewhere deep inside the codebase?
Related to this, we would like to catch problems early in the development cycle: if we find an error while writing our code initially,
then fixing it takes significantly less effort (and is much less costly) than if the problem happens in an application which is already deployed to production.
TypeCheck gives you the handholds to tackle this situation.

  
    
  
  What about Elixir's built-in typespecs and Dialyzer?


Elixir (and Erlang) come with a nice description for the types of the values passed between functions, called 'Typespecs'.
However, by default these typespecs are just used for documentation.
They are not used in any way to restrict, or even warn when your code is not following them correctly.
Somewhat more recently, tools like Dialyzer / Dialyxir have been introduced in the ecosystem.
These perform a static check of the source-code (that is, they look at the code as written without executing it) to catch some potential mis-uses.
Dialyzer has however three commonly mentioned drawbacks:
	On larger codebases it becomes prohibitively slow to run;
	It contains both 'false negatives' (improper usage that it missed) as well as 'false positives' (warnings about things which are actually OK);
	Some warnings can be outright cryptic to resolve.

Dialyzer is still a very useful tool, but it is not a cure-all.
As such, there was definite room in this space for improvement.

  
    
  
  Introducing TypeCheck


Using TypeCheck is as simple as adding a use TypeCheck to the module(s) you want to add checks to.
For each type-specification ('type') and function-specification ('spec') which is defined using TypeCheck, the following four features become available:
	'Normal' Elixir Typespecs for usage with pre-existing external tools (like e.g. Dialyzer).
	Documentation with extra detail not found in 'Normal' Elixir typespecs.
	Run-time type checks for all parameters to a function (if there is a failure, the function is used improperly) and of the returned value (if this fails, the function has a mistake).
	Data generators for all types (and specs), for usage in testing, especially property-tests and spectests (explained below).

Let's take a look at how TypeCheck can be used in practice.
This will help to see how the run-time type checks work, as well as how you can use TypeCheck's spectests to supercharge your testing.

  
    
  
  An Example


Let's say we are writing a module to work with five-star ratings.
defmodule Rating do
  @type t() :: %Rating{value: 1..5, author: String.t()}
  defstruct [:value, :author]

  @spec average(list(t())) :: number()
  def average(ratings) do
    values = Enum.map(ratings, &(&1.value))
    Enum.sum(values) / Enum.count(values)
  end
end
In good Elixir style, the functions and the struct have already received type signatures, even though they are currently only used for documentation.
(Speaking of documentation: it is good practice to add documentation to all public modules and functions. To keep the examples in this article brief, they have been elided.)
From the function-specification, you can already see how the function average is intended to be used:
When passing a list of ratings, we will return a single number: the average.
Let's try calling it with a couple of inputs:
iex(8)> Rating.average([%Rating{author: "Joe", value: 5}, %Rating{author: "Mike", value: 4}])
4.5
iex(8)> Rating.average([%Rating{author: "Robert", value: 3}])
3.0
So far so good.
Now, let's try what happens when someone makes a mistake:
iex> Rating.average(%Rating{author: "José", value: 3})
** (Protocol.UndefinedError) protocol Enumerable not implemented for %Rating{author: "José", value: 3} of type Rating (a struct). This protocol is implemented for the following type(s): Map, Range, List, MapSet, GenEvent.Stream, Stream, Date.Range, HashDict, IO.Stream, HashSet, Function, File.Stream
    (elixir 1.12.0) lib/enum.ex:1: Enumerable.impl_for!/1
    (elixir 1.12.0) lib/enum.ex:141: Enumerable.reduce/3
    (elixir 1.12.0) lib/enum.ex:3923: Enum.map/2
    iex:19: Rating.average/1
Oof!
Clearly something is going wrong here, but if one were to encounter this error somewhere deep in a codebase,
it would not be immediately obvious that the problem was that we were calling the function incorrectly.
Even worse is if we happen to pass a list of non-ratings to the function:
iex> Rating.average([1, 2, 3])
** (ArgumentError) you attempted to apply :value on 1. If you are using apply/3, make sure the module is an atom. If you are using the dot syntax, such as map.field or module.function(), make sure the left side of the dot is an atom or a map
    :erlang.apply(1, :value, [])
    iex:19: anonymous fn/1 in Rating.average/1
    (elixir 1.12.0) lib/enum.ex:1553: Enum."-map/2-lists^map/1-0-"/2
    iex:19: Rating.average/1
And finally, there is nothing preventing the creation of malformed rating-objects.
While we have specified in our type that the rating's value should only ever be in the range 1..5,
this is not constrained anywhere in the code.
And if someone passes a nil rating, we'd get a ** (ArithmeticError) bad argument in arithmetic expression: nil + 0 error.
Also not very clear.
While we could sprinkle checks for this everywhere, this would in the best case result in extremely 'defensive' and badly readable code.
And in the worst case, we might forget to add a check at certain places, still not giving us certainty.
Let's see how TypeCheck can improve this situation.

  
    
  
  Adding TypeCheck


In general, adding TypeCheck to a module only requires the following two steps:
	Add use TypeCheck at the top of the module.
	Replace all usage of @type with @type! and all usage of @spec with @spec!. (For the curious: There indeed are similarly overloaded versions of @typep! and @opaque! available.)

You're done!
Our example ratings module now looks like this:
defmodule Rating do
  use TypeCheck

  @type! t() :: %Rating{value: 1..5, author: String.t()}
  defstruct [:value, :author]

  @spec! average(list(t())) :: number()
  def average(ratings) do
    values = Enum.map(ratings, &(&1.value))
    Enum.sum(values) / Enum.count(values)
  end
end
With this change, correct usage of the function still returns the expected results:
iex(8)> Rating.average([%Rating{author: "Joe", value: 5}, %Rating{author: "Mike", value: 4}])
4.5
iex(8)> Rating.average([%Rating{author: "Robert", value: 3}])
3.0
So far, so good. Now let's look at what happens when the function is used incorrectly:
iex(20)> Rating.average(%Rating{author: "José", value: 3})
** (TypeCheck.TypeError) At iex:17:
    The call to `average/1` failed,
    because parameter no. 1 does not adhere to the spec `list(%Rating{author: binary(), value: number()})`.
    Rather, its value is: `%Rating{author: "José", value: 3}`.
    Details:
      The call `average(%Rating{author: "José", value: 3})`
      does not adhere to spec `average(list(%Rating{author: binary(), value: number()})) :: number()`. Reason:
        parameter no. 1:
          `%Rating{author: "José", value: 3}` does not check against `list(%Rating{author: binary(), value: number()})`. Reason:
            `%Rating{author: "José", value: 3}` is not a list.
        lib/type_check/spec.ex:165: Rating.average/1

Look at that! Not only do we see that the problem is is caused by the call to the function itself,
but the cause of the problem is also very clear: the passed value is not a list.
Here's our second mistake:
iex> Rating.average([1, 2, 3])
** (TypeCheck.TypeError) At iex:17:
    The call to `average/1` failed,
    because parameter no. 1 does not adhere to the spec `list(%Rating{author: binary(), value: number()})`.
    Rather, its value is: `[1, 2, 3]`.
    Details:
      The call `average([1, 2, 3])`
      does not adhere to spec `average(list(%Rating{author: binary(), value: number()})) :: number()`. Reason:
        parameter no. 1:
          `[1, 2, 3]` does not check against `list(%Rating{author: binary(), value: number()})`. Reason:
            at index 0:
              `1` does not check against `%Rating{author: binary(), value: number()}`. Reason:
                `1` is not a map.
        lib/type_check/spec.ex:165: Rating.average/1

This time too, the error is much clearer, showing that the innermost reason of the type-checking failure is that the passed number is not a map.
Now, let's also look at what happens when we pass a malformed Rating struct:
iex> Rating.average([%Rating{author: "root", value: -100}])
** (TypeCheck.TypeError) At iex:21:
    The call to `average/1` failed,
    because parameter no. 1 does not adhere to the spec `list(%Rating{author: binary(), value: 1..5})`.
    Rather, its value is: `[%Rating{author: "root", value: -100}]`.
    Details:
      The call `average([%Rating{author: "root", value: -100}])`
      does not adhere to spec `average(list(%Rating{author: binary(), value: 1..5})) :: number()`. Reason:
        parameter no. 1:
          `[%Rating{author: "root", value: -100}]` does not check against `list(%Rating{author: binary(), value: 1..5})`. Reason:
            at index 0:
              `%Rating{author: "root", value: -100}` does not check against `%Rating{author: binary(), value: 1..5}`. Reason:
                under key `:value`:
                  `-100` does not check against `1..5`. Reason:
                    `-100` falls outside the range 1..5.
        lib/type_check/spec.ex:165: Rating.average/1

Much nicer! Now, all functions which have a @spec! will have there inputs checked properly,
and passing them a malformed rating-struct is impossible without cluttering our code.
As a final example, say we alter the implementation of the function to something which is clearly wrong,
such as always returning the string "something else":
iex> Rating.average([%Rating{author: "Joe", value: 5}, %Rating{author: "Mike", value: 4}])
** (TypeCheck.TypeError) The call to `average/1` failed,
    because the returned result does not adhere to the spec `number()`.
    Rather, its value is: `"something else"`.
    Details:
      The result of calling `average([%Rating{author: "Marten", value: 1}])`
      does not adhere to spec `average(
      list(%Rating{author: binary(), value: 1..5})) :: number()`. Reason:
        Returned result:
          `"something else"` is not a number.
        lib/type_check/spec.ex:194: Rating.average/1
In this case, you can clearly see that the problem is caused by the return value, and why.

  
    
  
  Efficiency of runtime checks


TypeCheck adds its runtime checks by wrapping your functions (using defoverridable).
This means that the Elixir and Erlang compilers are able to optimize the checks to their liking.
Therefore, code added by TypeCheck is at the very least not slower than any hand-written parameter-checking code.
In many cases, the compiler is even smart enough to combine the type-check with a case, if or cond-expression that your function implementation itself contains,
so even in those cases no duplicate checks are done.
That said, there are certain cases in which the type-checks might still be too slow, since by default TypeCheck performs a deep check for
all parameters to a function. In the case of for instance a large collection or a deeply-nested 'tree of structs' this might still be too slow.
In those cases, you might want to turn off TypeCheck in certain environments (such as production) while still keeping it available in the development and testing environments.
Be sure to benchmark before making the decision to turn TypeCheck off, as there is a high probability that the bottlenecks in your code are actually found elsewhere.
And finally, regardless of whether the checks are used or not, there is one more way in which TypeCheck's types and specs are useful: Automated testing.

  
    
  
  Spectests


Runtime type-checks give an early notice whether a function is being used properly or improperly.
In essence, we check 'Does the caller of the function adhere to the function's specification?'
However, to get more certainty about the correctness¹ of our code, we'd also like to check the opposite: 'Does the function itself adhere to its specification?'
This is where 'function-specification tests', or spectests for short, come in.

  
    
  
  What is a spectest?


A spectest is a property-based test in which
we check whether the function adheres to its specification's invariants
(also known as the function's contract or its preconditions and postconditions).
This is done by generating a large amount of possible function inputs,
and for each of these, check whether the function:
	Does not raise an exception.
	Returns a result that type-checks against the spec's return-type.

Spectests are given its own test-category in ExUnit, for easier recognition
(Just like 'doctests' and 'properties' are different from normal tests, so are 'spectests'.)
If you're new to property-based testing, then 'Overview of Property-based testing'-section of the ExUnitProperties' documentation
might be a good place for a general overview.
¹: Because of the nature of property-based testing, we can never know for 100% sure that a function is correct. However, with every new randomly-generated test-case, the level of confidence grows a little. So while we can never by fully sure, we are able to get asymptotically close to it.
  
    
  
  Spectesting our example


To add a spectest, we need to use TypeCheck.ExUnit in our testing file,
and then call spectest YourModuleName. This accepts options similarly to doctest which you might already be familiar with.
To use spectests (and data generation in general), TypeCheck requires on the optional dependency StreamData,
so be sure to add it to your project's mix deps.
Let's spectest the Rating module, to make sure our code does not contain any mistakes.
defmodule RatingTest do
  use ExUnit.Case, async: true
  use TypeCheck.ExUnit

  spectest Rating
end
$ mix test


  1) spectest average(list(%Rating{author: binary(), value: 1..5})) :: number() (RatingTest)
     test/rating_test.exs:5
     Spectest failed (after 0 successful runs)

     Input: Rating.average([])

     ** (ArithmeticError) bad argument in arithmetic expression

     code: #TypeCheck.Spec<  average(list(%Rating{author: binary(), value: 1..5})) :: number() >
     stacktrace:
       (type_check_guide 0.1.0) lib/rating.ex:10: Rating."average (overridable 1)"/1
       lib/type_check/ex_unit.ex:5: anonymous fn/1 in RatingTest."spectest average(\n  list(%Rating{author: binary(), value: 1..5})\n)\n::\nnumber()"/1
       (stream_data 0.5.0) lib/stream_data.ex:2102: StreamData.check_all/7
       lib/type_check/ex_unit.ex:5: (test)

..

Finished in 0.1 seconds (0.1s async, 0.00s sync)
1 doctest, 1 spectest, 1 test, 1 failure
Oof! Our code contained a mistake!
It turns out that when Rating.average is given an empty list, we end up dividing by zero!
Some math-savvy readers might have seen this coming from a mile away.
However, I'm sure that some of you will have been surprised by this problem 😇.
Of course this is only an educational example of the kind of issues one might encounter in a real codebase.
We might resolve this issue in two ways:
	Decide that an empty list should never be passed, and therefore restrict the parameter types further.
For instance, we could change it from a list(Rating.t()) to a nonempty_list(Rating.t()).
This means that when someone tries passing it an empty list, they will immediately be notified that this is not supported,
using the clear error messages as seen in the earlier examples.
Changing the spec this way will also make the spectest pass, as empty lists will no longer be generated.
	Decide that empty lists are a correct input, but that the output will be changed from number() to {:ok, number()} | {:error, :empty},
asking code which uses average to handle the possibility of an error-result being returned.


In either case, after these changes the spectest will pass.

  
    
  
  More general properties


While spectests are a very simple and code-light way to test your functions,
it is also possible to generate arbitrary values from any type outside of a spectest, for use in other, more specialized property-based tests.
See TypeCheck.Type.StreamData.to_gen/1 for more info.

  
    
  
  There is more


We have covered the most important features of TypeCheck,
but there is more to discover, such as:
	The error-formatter which is reconfigurable and could be overloaded by custom implementations.
	TypeCheck itself is extensively property-tested using its own types.
	Most of TypeCheck's type-construction functions use TypeCheck's checks itself, which mean that you will get the same clear error messages when making a mistake while constructing a type (but this time during compile-time. nifty, eh?!)
	TypeCheck supports 'type guards' for if you want to add extra custom constraints to any particular type.
	TypeCheck supports 'unquote fragments' for when you want to go ham with metaprogramming.


  
    
  
  Summary


In this guide, you have seen how TypeCheck can be used and what value it can add to your projects.
We have seen how TypeCheck can be used in a general project to add runtime checks to your functions,
as well as how to use the spectest macro to get automatic property-tests that check whether your functions
follow their specs.
TypeCheck currently is at version 0.7.0 and in active development.
Feedback, issues and pull requests are very welcome!
Thank you very much for sticking through this long read with me 💚.
I wish you a wonderful day!
~Marten/Qqwy


  

    
Comparing TypeCheck and Elixir Typespecs
    

TypeCheck is intended to be a drop-in supplement to Elixir typespecs. With very few exceptions, all of Elixir's typespecs are supported by TypeCheck. Below is a breakdown of supported typespec syntax in TypeCheck.
In the tables below:
	'✅' indicates that something is supported
	'❌' indicates that something is not supported.
	'⌛' indicates that something is not currently supported, but there are plans to add support for it in the near future.


  
    
  
  Basic Types


	Type	Supported?	Notes
	any()	✅	the top type, the set of all terms
	none()	✅	the bottom type, contains no terms
	atom()	✅	
	map()	✅	any map
	pid()	✅	process identifier
	port()	✅	port identifier
	reference()	✅	
	tuple()	✅	tuple of any size
	float()	✅	
	integer()	✅	
	neg_integer()	✅	..., -3, -2, -1
	non_neg_integer()	✅	0, 1, 2, 3, ...
	pos_integer()	✅	1, 2, 3, ...
	list(type)	✅	proper list
	nonempty_list(type)	✅	non-empty proper list
	maybe_improper_list(content_type, termination_type)	✅	proper or improper list
	nonempty_improper_list(content_type, termination_type)	✅	improper list
	nonempty_maybe_improper_list(content_type, termination_type)	✅	non-empty proper or improper list


  
    
  
  Literals


	Type	Supported?	Notes
	true	✅	
	false	✅	
	nil	✅	
	<<>>	✅	empty bitstring
	<<_::size>	✅	size is 0 or a positive integer
	<<_::_*unit>>	✅	unit is an integer from 1 to 256
	<<_::size, _::_*unit>>	✅	
	(-> type)	✅¹	0-arity, returns type
	(type1, type2 -> type)	✅¹	2-arity, returns type
	(... -> type)	✅¹	any arity, returns type
	1	✅	integer
	1..10	✅	range
	[type]	✅	list with any number of type elements
	[]	✅	empty list
	[...]	✅	shorthand for nonempty_list(any())
	[type, ...]	✅	shorthand for nonempty_list(type)
	[key: value_type]	✅	keyword list with key :key of value_type
	%{}	✅	empty map
	%{key: value_type}	✅	map with required (atom) key :key of value_type
	%{key_type => value_type}	✅	map with required pairs of key_type and value_type
	%{required(key_type) => value_type}	✅²	map with required pairs of key_type and value_type
	%{optional(key_type) => value_type}	✅²	map with optional pairs of key_type and value_type
	%SomeStruct{}	✅	struct with all fields of any type
	%SomeStruct{key: value_type}	✅	struct with required key :key of value_type
	%{key: value_type, optional(opt_key_type) => opt_value_type}	✅³	struct with required key :key of value_type, and zero or more pairs of opt_key_type and opt_value_type
	{}	✅	empty tuple
	{:ok, type}	✅	two-element tuple with an atom and any type

¹: Functions passed as parameters can only be fully checked once they are called. 
TypeCheck wraps them in a 'wrapper function' which performs the correct check on their input/output.
This wrapper will only run once the the function actually is called.
²: Only a single 'required' or 'optional' field in a map is currently supported. (Types which need more are fortunately very rare.)
³: Only optional is currently supported, and only a single one. (Types which need more are fortunately very rare.)

  
    
  
  Built-in types


	Type	Supported?	Notes
	term()	✅	any()
	arity()	✅	0..255
	as_boolean(t)	✅	t
	binary()	✅	<<_::_*8>>
	bitstring()	✅	<<_::_*1>>
	boolean()	✅	true | false
	byte()	✅	0..255
	char()	✅	0..0x10FFFF
	charlist()	✅	[char()]
	nonempty_charlist()	✅	[char(), ...]
	fun()	✅	(... -> any)
	function()	✅	fun()
	identifier()	✅	pid() | port() | reference()
	iodata()	✅	iolist() | binary()
	iolist()	✅	maybe_improper_list(byte() | binary() | iolist(), binary() | [])
	keyword()	✅	[{atom(), any()}]
	keyword(t)	✅	[{atom(), t}]
	list()	✅	[any()]
	nonempty_list()	✅	nonempty_list(any())
	maybe_improper_list()	✅	maybe_improper_list(any(), any())
	nonempty_maybe_improper_list()	✅	nonempty_maybe_improper_list(any(), any())
	mfa()	✅	{module(), atom(), arity()}
	module()	✅	atom()
	no_return()	✅	none()
	node()	✅	atom()
	number()	✅	integer() | float()
	struct()	✅	%{:__struct__ => atom(), optional(atom()) => any()}
	timeout()	✅	:infinity | non_neg_integer()


  
    
  
  🚀 TypeCheck Additions


TypeCheck adds the following extensions on Elixir's builtin typespec syntax:
	Type	Notes
	impl(protocol_name)	Checks whether the given value implements the particular protocol
	fixed_list(element_types)	Fixed size where element_types dictate types
	tuple(size)	Any types, but which has exactly size elements
	map(key_type, value_type)	Zero or more keys of key_type and values of value_type
	type when guard	A 'type guard', an extra check implemented in arbitrary code (see below)


  
    
  
  Defining Specifications


	Type	Supported?	Notes
	@type	✅	as @type!
	@opaque	✅	as @opaque!
	@typep	✅	as @typep!
	@spec	✅	as @spec!

✅ Basic Spec Definition
# typespecs
@spec function_name(type1, type2) :: return_type

# TypeCheck
@spec! function_name(type1, type2) :: return_type
❌ Spec Guards
# typespecs
@spec function(arg) :: [arg] when arg: atom
@spec function(arg1, arg2) :: {arg1, arg2} when arg1: atom, arg2: integer
@spec function(arg) :: [arg] when arg: var

# TypeCheck - unsupported
TypeCheck currently solely allows the usage of when to specify 'type guards' (see below).
Support for spec guards could be added. However:
	Their usage is quite rare.
	Each place where it is used, it matches 'exactly the same value'. Building this check is relatively tricky.

If you have a strong desire for this feature, please open an issue for it.
✅ Named Arguments
# typespecs
@spec days_since_epoch(year :: integer, month :: integer, day :: integer) :: integer
@type color :: {red :: integer, green :: integer, blue :: integer}

# TypeCheck
@spec! days_since_epoch(year :: integer, month :: integer, day :: integer) :: integer
@type! color :: {red :: integer, green :: integer, blue :: integer}
❌ Specification Overloads
# typespecs
@spec function(integer) :: atom
@spec function(atom) :: integer

# TypeCheck - unsupported
There is no intention to support this.
The implementation would be very difficult, and it is arguably good practice to have a single specification anyway.

  
    
  
  User Defined Types


✅ Basic Definition
# typespecs
@type type_name :: type
@typep type_name :: type
@opaque type_name :: type

# TypeCheck
@type! type_name :: type
@typep! type_name :: type
@opaque! type_name :: type
✅ Parameterized Types
# typespecs
@type dict(key, value) :: [{key, value}]

# TypeCheck
@type! dict(key, value) :: [{key, value}]
🚀 Type Guards
To add extra custom checks to a type, you can use a so-called 'type guard'. This is arbitrary code that is executed during a type-check once the type itself already matches.
You can use "named types" to refer to (parts of) the value that matched the type, and refer to these from a type-guard:
# typespecs - unsupported

# TypeCheck
@type! sorted_pair :: {lower :: number(), higher :: number()} when lower <= higher

  
    
  
  ✅ Remote Types


It is often useful to refer to types defined in other modules. These are called 'Remote types'.
Elixir's typespecs and TypeCheck both support remote types.
# typespecs
defmodule User do
  @type t() :: %User{name: String.t(), age: non_negative_integer()}
end

defmodule Greeter do
  @spec greet(User.t()) :: String.t()
  def greet(user) do
   # ... 
  end
end

# TypeCheck
defmodule User do
  use TypeCheck

  @type! t() :: %User{name: String.t(), age: non_negative_integer()}
end

defmodule Greeter do
  use TypeCheck

  @spec! greet(User.t()) :: String.t()
  def greet(user) do
   # ... 
  end
end

  
    
  
  Remote Type Overrides


From time to time we need to interface with modules written in other libraries (or the Elixir standard library) which do not expose their types through TypeCheck yet.
We want to be able to use those types in our checks, but they exist in modules that we cannot change ourselves.
The solution is to allow a list of ‘type overrides’ to be given as part of the options passed to use TypeCheck, which allow you to use the original type in your types and documentation, but have it be checked (and potentially property-generated) as the given TypeCheck-type.
Example:
defmodule Original do
  @type t() :: any()
end

defmodule Replacement do
  use TypeCheck
  @type! t() :: integer()
end

defmodule Example do
  use TypeCheck, overrides: [{&Original.t/0, &Replacement.t/0}]

  @spec! times_two(Original.t()) :: integer()
  def times_two(input) do
    input * 2
  end
end

  
    
  
  Elixir Standard Library Types


TypeCheck helpfully ships with the majority of the types in Elixir's Standard Library already implemented as default overrides. This means that your @spec! definitions can reference types like String.t(), Date.t() and Range.t() out of the box.
	Type	Supported?	Notes
	Access	✅	
	Agent	✅	
	Application	✅	
	Calendar	✅	
	Calendar.ISO	✅	
	Calendar.TimeZoneDatabase	✅	
	Code	✅	
	Collectable	✅	
	Config.Provider	✅	
	Date	✅	
	Date.Range	✅	
	DateTime	✅	
	Dict	❌	deprecated
	DynamicSupervisor	✅	
	Enum	✅	
	Enumerable	✅	
	Exception	✅	
	File	✅	
	File.Stat	✅	
	File.Stream	✅	
	Float	✅	
	Function	✅	
	GenEvent	❌	deprecated
	GenServer	✅	
	HashDict	❌	deprecated
	HashSet	❌	deprecated
	IO	✅	
	IO.ANSI	✅	
	IO.Stream	✅	
	Inspect	✅	
	Inspect.Algebra	✅	
	Inspect.Opts	✅	
	Keyword	✅	
	List.Chars	✅	
	Macro	✅	
	Macro.Env	✅	
	Map	✅	
	MapSet	✅	
	NaiveDateTime	✅	
	Node	✅	
	OptionParser	✅	
	Path	✅	
	Port	✅	
	Process	✅	
	Range	✅	
	Regex	✅	
	Registry	✅	
	Set	❌	deprecated
	Stream	✅	
	String	✅	
	String.Chars	✅	
	Supervisor	✅	
	Supervisor.Spec	❌	deprecated
	System	✅	
	Task	✅	
	Task.Supervisor	✅	
	Time	✅	
	URI	✅	
	Version	✅	
	Version.Requirement	✅	



  

    
Comparing TypeCheck and Norm
    


  
    
  
  Norm


Norm is an Elixir library for specifying the structure of data that can be used for both validation and data-generation.
On a superficial level, Norm and TypeCheck seem similar. However, there are important differences in their design considerations:
Primary Focus
Norm focuses on conforming values to specifications by re-using your existing validations. 
Norm also has a focus on 'open' schemas that are designed to allow systems to grow over time.
TypeCheck focuses on making the types your program is using explicit. 
This is done by retrofitting Elixir's built-in type syntax to allow you to use a single statement to create 
	an expanded type-/function-specification for in the documentation, 
	runtime type-checking code and
	data-generation for property-testing.

Syntax
Norm uses a new, guard-like function-call syntax.
Norm is light on the little syntactic sugar: Literal atoms and tuples containing specs as elements are treated as specs themselves. 
Anything else requires you to write a (dedicated or anonymous) validation function.
TypeCheck uses the same syntax that Elixir's built-in typespecs use, which is already familiar to many Elixir developers.
This makes a TypeCheck @type! or @spec! often much shorter than the equivalent Norm spec or @contract.
A couple of syntactical examples:
A simple 'manual' validation. (This is common Norm usage but manual validations are more rare in TypeCheck.)
# Norm:
iex> Norm.conform!(123, spec(is_integer() and &(&1 > 0)))
123
# TypeCheck
iex> TypeCheck.conforms!(123, non_neg_integer())
# or:
iex> TypeCheck.conforms!(123, x :: integer() when x >= 0)
Defining custom type-specifications ('specs' in Norm parlance) and function-specifications ('contracts' in Norm parlance):
# Norm:
defmodule Color do
  import Norm
  def rgb(), do: spec(is_integer() and &(&1 in 0..255))
  def hex(), do: spec(is_binary() and &String.starts_with?(&1, "#"))
  
  @contract rgb_to_hex(r :: rgb(), g :: rgb(), b :: rgb()) :: hex()
  def rgb_to_hex(r, g, b) do
    # ...
  end
end
# TypeCheck:
defmodule Color do
  use TypeCheck
  @type! rgb :: 0..255
  @type! hex :: (str :: binary() when String.starts_with?(str, "#"))
  
  @spec! rgb_to_hex(rgb(), rgb(), rgb()) :: hex()
  def rgb_to_hex(r, g, b) do
    # ...
  end
end
Defining a more complicated specification of a custom structure with multiple fields:
# Norm:
defmodule User do
  use Norm

  defstruct [:name, :age]
  def age_spec(), do: spec(is_integer() and &(&1 >= 0))
  def s() do
    schema(%{
      name: spec(is_binary()),
      age: age_spec(),
    })
  end
  
  @contract new(name :: spec(is_binary()), age :: age_spec()) :: s()
  def new(name, age) do
    %__MODULE__{name: name, age: age}
  end
  
  @contract ensure_old_enough(user :: s(), limit :: age_spec()) :: alt(success: {:ok, s()}, problem: {:error, spec(is_binary())})
  def ensure_old_enough(user, limit) do
    if user.age >= limit do
      {:ok, user}
    else
      {:error, "not old enough"}
    end
  end
end
# TypeCheck:
defmodule User do
  use TypeCheck
  defstruct [:name, :age]
  @type! age :: non_neg_integer()
  @type! t :: %User{name: binary(), age: age()}

  @spec! new(binary(), age()) :: t()
  def new(name, age) do
    %User{name: name, age: age}
  end

  @spec! ensure_old_enough(t(), age()) :: {:ok, t()} | {:error, binary()}
  def ensure_old_enough(user, limit) do
    if user.age >= limit do
      {:ok, user}
    else
      {:error, "not old enough"}
    end
  end
end
Error messages
Norm does not particularly focus on readable error messages (although that might change in the future).
TypeCheck heavily focuses on creating humanly-readable error-messages when a value does not type-check,
creating a deeply nested error message indicating the cause of a top-level error (see the main README for some examples of this). 
TypeCheck's error messages are based on a pluggable formatter for which custom alternatives can be provided.
As an example, consider the execution using the respective definitions of User.ensure_old_enough above:
User.ensure_old_enough(%User{name: "Marten", age: 0.5}, 21)
** (Norm.MismatchError) Could not conform input:
val: 0.5 in: :age fails: is_integer()
    (norm 0.13.0) lib/norm.ex:65: Norm.conform!/2
    (norm_example 0.1.0) lib/norm_example.ex:38: anonymous fn/2 in User.ensure_old_enough/2
    (elixir 1.12.0) lib/enum.ex:2356: Enum."-reduce/3-lists^foldl/2-0-"/3
    (norm_example 0.1.0) lib/norm_example.ex:38: User.ensure_old_enough/2
** (TypeCheck.TypeError) At lib/type_check_example.ex:21:
The call to `ensure_old_enough/2` failed,
because parameter no. 1 does not adhere to the spec `%User{age: non_neg_integer(), name: binary()}`.
Rather, its value is: `%User{age: 0.5, name: "Marten"}`.
Details:
  The call `ensure_old_enough(%User{age: 0.5, name: "Marten"}, 21)`
  does not adhere to spec `ensure_old_enough(%User{age: non_neg_integer(), name: binary()}, non_neg_integer())
::
{:ok, %User{age: non_neg_integer(), name: binary()}} | {:error, binary()}`. Reason:
    parameter no. 1:
      `%User{age: 0.5, name: "Marten"}` does not check against `%User{age: non_neg_integer(), name: binary()}`. Reason:
        under key `:age`:
          `0.5` is not a non-negative integer.
    (type_check_example 0.1.0) lib/type_check/spec.ex:165: User.ensure_old_enough/2

Another example, displaying the difference between error messages when the problem is in the value returned by the function:
# Given the `rgb_to_hex` function as defined above, but with an implementation not adhering to its spec/contract
  def rgb_to_hex(r, g, b) do
    {:ok, 42}
  end
iex> Color.rgb_to_hex(10, 20, 30)
** (Norm.MismatchError) Could not conform input:
val: {:ok, 42} fails: is_binary()
    (norm 0.13.0) lib/norm.ex:65: Norm.conform!/2

iex> Color.rgb_to_hex(10, 20, 30)
** (TypeCheck.TypeError) The call to `rgb_to_hex/3` failed,
because the returned result does not adhere to the spec `(str :: binary() when String.starts_with?(str, "#"))`.
Rather, its value is: `{:ok, 42}`.
Details:
  The result of calling `rgb_to_hex(10, 20, 30)`
  does not adhere to spec `rgb_to_hex(0..255,  0..255,  0..255) :: (str :: binary() when String.starts_with?(str, "#"))`. Reason:
    Returned result:
      `{:ok, 42}` does not check against `(str :: binary() when String.starts_with?(str, "#"))`. Reason:
        `{:ok, 42}` does not check against `str :: binary()`. Reason:
          `{:ok, 42}` is not a binary.
    (type_check_example 0.1.0) lib/type_check/spec.ex:194: Color.rgb_to_hex/3

Execution & Efficiency
In Norm, while wrapping functions with a contract happens at compile-time, 
all contracts and specs are resolved at runtime.
This makes Norm's internals less metaprogramming-heavy and easily allows specs to be created and manipulated dynamically at runtime, 
but it does mean that the compiler is not able to optimize the type-checking code at all, and specs are re-evaluated every time a function is called.
TypeCheck requires¹ types to be defined at compile-time and injects the type-checking code into your functions and modules before they are compiled, 
allowing type-checking to be optimized.
If there is overlap between the parts of your parameters being checked by TypeCheck and the logic of your function,
the BEAM compiler will in most cases be able to combine these into a single check.
¹: In normal usage. Escape hatches to work with types defined at runtime exist. (c.f. TypeCheck.dynamic_conforms/2 and variants)
Documentation
Norm does not focus on documentation.
Norm's specs are normal functions which you can document manually using @doc if you wish. 
Norm's @contracts are not used for documentation purposes.
TypeCheck adds @type/@typep/@opaque attributes for the types you specify, making them show up in your documentation 
and allowing you to use the same type definitions for tools like Dialyzer. 
You can also use the t helper to look them up in IEx. 
Documentation can be added to these types by using @typedoc (just like for normal typespecs).
Function-specifications created with TypeCheck will also add @spec-attributes, which will end up in the documentation of your functions and are similarly useful for e.g. Dialyzer.
Data Generation & Testing
It is very useful to generate examples of good data to be used for property testing.
Both Norm and TypeCheck have this capability, by using :stream_data as an optional dependency.
Norm's generators (only) work when the first predicate in a spec(...) is one of (a subset of) Elixir's built-in guard-clauses. 
If your spec is too restrictive, you'll have to manually provide a custom data generator as well.
TypeCheck builds more complicated generators out of simple ones just as it builds complicated types out of simple ones. 
This means that virtually all Elixir types can be turned into generators without extra effort of the user. 
It is only when 'type guards' are used to add arbitrary checks to a type that you might up with a generator that is too restrictive. 
TypeCheck supports nearly all of Elixir's builtin types, as well as many of the remote types that are part of Elixir's standard library (Range.t, MapSet.t, List.t, Enum.t etc.)
Furthermore, TypeCheck allows overriding the generator for a type (c.f. the TypeCheck.Type.StreamData.wrap_with_gen/2 macro).
Finally and maybe most importantly, TypeCheck ships with the spectest macro. (c.f. TypeCheck.ExUnit.spectest/2)
spectest works similarly to doctest but rather than testing all code snippets in the module's documentation,
it will automatically run a property-test to check for each @spec!-ced function in a module, whether it correctly follows its spec.

Norm and TypeCheck are but two different dots in the datastructure-validation design space. Norm is definitely worth checking out!


  

    
TypeCheck 
    



      
Fast and flexible runtime type-checking.
The main way to use TypeCheck is by adding use TypeCheck in your modules.
This will allow you to use the macros of TypeCheck.Macros in your module,
which are versions of the normal type-specification module attributes
with an extra exclamation mark at the end:  @type!, @spec!, @typep! and @opaque!.
It will also bring all functions in TypeCheck.Builtin in scope,
which is usually what you want as this allows you to
use all types and special syntax that are built-in to Elixir
in the TypeCheck specifications.
Using these, you're able to add function-specifications to your functions
which will wrap them with runtime type-checks.
You'll also be able to create your own type-specifications that can be used
in other type- and function-specifications in the same or other modules later on:
defmodule User do
  use TypeCheck
  defstruct [:name, :age]
  @type! age :: non_neg_integer()
  @type! t :: %User{name: binary(), age: age()}

  @spec! new(binary(), age()) :: t()
  def new(name, age) do
    %User{name: name, age: age}
  end

  @spec! old_enough?(t(), age()) :: boolean()
  def old_enough?(user, limit) do
    user.age >= limit
  end
end
Finally, you can test whether your functions correctly adhere to their specs,
by adding a spectest in your testing suite. See TypeCheck.ExUnit.spectest/2 for details.

  
    
  
  Types and their syntax


TypeCheck allows types written using (essentially) the same syntax as Elixir's builtin typespecs.
This means the following:
	literal values like :ok, 10.0 or "my string" desugar to a call to TypeCheck.Builtin.literal/1, which is a type that matches only exactly that value.
	Basic types like integer(), float(), atom() etc. are directly supported (and exist as functions in TypeCheck.Builtin).
	tuples of types like {atom(), integer()} are supported (and desugar to TypeCheck.Builtin.fixed_tuple/1)
	maps where keys are literal values and the values are types like %{a: integer(), b: integer(), 42 => float()} desugar to calls to TypeCheck.Builtin.fixed_map/1.	The same happens with structs like %User{name: binary(), age: non_neg_integer()}


	sum types like integer() | string() | atom() are supported, and desugar to calls to TypeCheck.Builtin.one_of/1.

	Ranges like lower..higher are supported, matching integers within the given range. This desugars into a call to TypeCheck.Builtin.range/1.


  
    
  
  Currently unsupported features


The following typespec syntax can not currently be used in TypeCheck. This will hopefully change in future versions of the library.
	Literal maps with required(...) and optional(...) keys. (TypeCheck does already support literal maps with a fixed set of keys, as well as maps with any number of key-value-pairs of fixed types. It is the special syntax that might mix these approaches that is not supported yet.)


  
    
  
  Extensions


TypeCheck adds the following extensions on Elixir's builtin typespec syntax:
	fixed-size lists containing types like [1, 2, integer()] are supported, and desugar to TypeCheck.Builtin.fixed_list/1.
This example matches only lists of 3 elements where the first element is the literal 1, the second the literal 2 and the last element any integer.
Elixir's builtin typespecs do not support fixed-size lists.
	named types like x :: integer() are supported; these are useful in combination with "type guards" (see the section below).
	"type guards" using the syntax some_type when arbitrary_code are supported, to add extra arbitrary checks to a value for it to match the type. (See the section about type guards below.)
	lazy(some_type), which defers type-expansion until during runtime. This is required to be able to expand recursive types. C.f. TypeCheck.Builtin.lazy/1


  
    
  
  Named Types Type Guards


To add extra custom checks to a type, you can use a so-called 'type guard'.
This is arbitrary code that is executed during a type-check once the type itself already matches.
You can use "named types" to refer to (parts of) the value that matched the type, and refer to these from a type-guard:
type sorted_pair :: {lower :: number(), higher :: number()} when lower <= higher
iex> TypeCheck.conforms!({10, 20}, sorted_pair)
{10, 20}
iex> TypeCheck.conforms!({20, 10}, sorted_pair)
** (TypeCheck.TypeError) `{20, 10}` does not match the definition of the named type `TypeCheckTest.TypeGuardExample.sorted_pair`
    which is: `TypeCheckTest.TypeGuardExample.sorted_pair
    ::
    (sorted_pair :: {lower :: number(), higher :: number()} when lower <= higher)`. Reason:
      `{20, 10}` does not check against `(sorted_pair :: {lower :: number(), higher :: number()} when lower <= higher)`. Reason:
        type guard:
          `lower <= higher` evaluated to false or nil.
          bound values: %{higher: 10, lower: 20, sorted_pair: {20, 10}}
Named types are available in your guard even from the (both local and remote) types that you are using in your time, as long as those types are not defined as opaque types.

  
    
  
  Manual type-checking


If you want to check values against a type outside of the checks the @spec! macro
wraps a function with,
you can use the conforms/2/conforms?/2/conforms!/2 macros in this module directly in your code.
These are evaluated at compile time which means the resulting checks will be optimized by the compiler.
Unfortunately it also means that the types passed to them have to be known at compile time.
If you have a type that is constructed dynamically at runtime, you can resort to
dynamic_conforms/2 and variants.
Because these variants have to evaluate the type-checking code at runtime,
these checks are not optimized by the compiler.

  
    
  
  Introspection


To allow checking what types and specs exist,
the introspection function __type_check__/1 will be added to a module when use TypeCheck is used.
	YourModule.__type_check__(:types) returns a keyword list of all {type_name, arity}
pairs for all types defined in the module using @type!/@typep! or @opaque!.
	YourModule.__type_check__(:specs) returns a keyword list of all {function_name, arity}
pairs for all functions in the module wrapped with a spec using @spec!.

Note that these lists might also contain private types / private function names.

TypeCheck.Defstruct 
    



      
Implements the defstruct! macro.
To use this macro:
	Ensure you use TypeCheck in your module
	Also use TypeCheck.Defstruct

And now call defstruct!/1 when you want to define a struct.

TypeCheck.ExUnit 
    



      
Provides macros for 'spectests': spec-automated property-testing.
The core macro exposed by this module is spectest/2, which
will will check for all function-specs in the given module,
whether those functions correctly follow the spec.
To use this functionality, add use TypeCheck.ExUnit to your testing module.
Currently, spectesting uses StreamData under the hood.
This means that to use the spectest functionality,
you need to add the :stream_data dependency to your application
(it is an optional dependency of TypeCheck.)
In the future, support for other property-generating libraries might be added.

  
    
  
  What is a spectest?


A 'function-specification test' is a property-based test in which
we check whether the function adheres to its invariants
(also known as the function's contract or preconditions and postconditions).
We generate a large amount of possible function inputs,
and for each of these, check whether the function:
	Does not raise an exception.
	Returns a result that type-checks against the spec's return-type.
(To be precise, if an incorrect result is returned, the function
is wrapped in will end up raising an exception for this.)

While @spec!s themselves ensure that callers do not mis-use your function,
a spectest ensures¹ that the function itself is working correctly.
Spectests are given its own test-category in ExUnit, for easier recognition
(Just like 'doctests' and 'properties' are different from normal tests, so are 'spectests'.)
¹: Because of the nature of property-based testing, we can never know for 100% sure
that a function is correct. However, with every new randomly-generated
test-case, the level of confidence grows a little. So while we
can never by fully sure, we are able to get asymptotically close to it.

TypeCheck.External 
    



      
Working with regular Elixir and Erlang @spec and @type definitions.

  
    
  
  Experimental


This module is experimental.
The API of the various functions in this module are not yet stable;
they might change slightly in future minor versions of the library.
If you encounter a problem, please, open an issue.

TypeCheck.Macros 
    



      
Contains the @spec!, @type!, @typep!, @opaque! macros to define runtime-checked function- and type-specifications.

  
    
  
  Usage


This module is included by calling use TypeCheck.
This will set up the module to use the special macros.
Usually you'll want to use the module attribute-style of the macros, like
@spec! and @type!.
Using these forms has two advantages over using the direct calls:
	Syntax highlighting will highlight the types correctly
and the Elixir formatter will not mess with the way you write your type.
	It is clear to people who have not heard of TypeCheck before that @type! and @spec!
will work similarly to resp. @type and @spec.


  
    
  
  Avoiding naming conflicts with TypeCheck.Builtin


If you want to define a type with the same name as one in TypeCheck.Builtin,
(which is not particularly recommended),
you should hide those particular functions from TypeCheck.Builtin by adding
import TypeCheck.Builtin, except: [...]
below use TypeCheck manually.

  
    
  
  Calling the explicit implementations


In case you are working in an environment where the @/1 is already overridden
by another library, you can still use this library,
by simply adding import TypeCheck.Macros, except: [@: 1] to your module
and calling the direct versions of the macros instead.

  
    
  
  TypeCheck and metaprogramming


In certain cases you might want to use TypeCheck to dynamically generate
types or functions, such as to add @spec!-s to functions
that themselves are dynamically generated.
TypeCheck's macros support 'unquote fragments',
just like many builtin 'definition' constructs like def, but also @type do.
(c.f. Elixir.Kernel.SpecialForms.quote/2 for more details about unquote fragments.)
An example:
defmodule MetaExample do
  use TypeCheck
  people = ~w[joe robert mike]a
  for name <- people do
    @type! unquote(name)() :: %{name: unquote(name), coolness_level: :high}
  end
end
iex> MetaExample.joe
#TypeCheck.Type< TypeCheck.MacrosTest.MetaExample.joe() :: %{coolness_level: :high, name: :joe} >

iex> MetaExample.mike
#TypeCheck.Type< TypeCheck.MacrosTest.MetaExample.mike() :: %{coolness_level: :high, name: :mike} >

Macros
Inside macros, we use unquote fragments in the same way.
There is however one more thing to keep in mind:
You'll need to add a call to import Kernel, except: [@: 1] in your macro (before the quote)
to make sure you can call @type!, @spec! etc.
This is a subtle consequence of Elixir's macro-hygiene rules.
See this issue on Elixir's GitHub repository for more info
(Alternatively, directly calls to type!, spec! etc. are possible without overriding the import.)
An example:
defmodule GreeterMacro do
  defmacro generate_greeter(greeting) do
    import Kernel, except: [@: 1] # Ensures TypeSpec's overridden `@` is used in the quote
    quote do
      @spec! unquote(greeting)(binary) :: binary
      def unquote(greeting)(name) do
        "#{greeting}, #{name}!"
      end
    end
  end
end

defmodule GreeterExample do
  use TypeCheck
  require GreeterMacro

  GreeterMacro.generate_greeter(:hi)
  GreeterMacro.generate_greeter(:hello)
end
iex> GreeterExample.hi("John")
"hi, John!"

iex> GreeterExample.hello("Frank")
"hello, Frank!"

iex> GreeterExample.hi(42)
** (TypeCheck.TypeError) At test/type_check/macros_test.exs:32:
    The call to `hi/1` failed,
    because parameter no. 1 does not adhere to the spec `binary()`.
    Rather, its value is: `42`.
    Details:
      The call `hi(42)`
      does not adhere to spec `hi(binary()) :: binary()`. Reason:
        parameter no. 1:
          `42` is not a binary.

About use TypeCheck
The use TypeCheck statement adds an @before_compile-hook to the final module,
which is used to wrap functions with the specified runtime type-checks.
This means that some care needs to be taken to ensure that a call to use TypeCheck exists
in the final module, if you're generating specs dynamically from inside macros.
Hiding the autogenerated typespec
By default, TypeCheck will automatically generate @type, @opaque and @spec-attributes,
which will be shown in the documentation, as well as used by tools such as Dialyzer.
In rare situations, TypeCheck might try to generate typespecs which are invalid.
(In such case, please open a bug report!)
Or sometimes, you might want to alter the type which is exported.
In such situations, you can disable the autogeneration of these attributes,
by calling @autogen_typespec false just before the next @type!/@opaque!/@spec!:
defmodule AutogenTypespecsExample do
  use TypeCheck

  # The typespec of `foo` is auto-generated:
  # A line `@type foo() :: integer()` will be visible in the documentation/Dialyzer.
  @type! foo() :: integer()

  # The typespec of `bar` is _not_ auto-generated.
  # As such, we could write a completely different `@type` (or leave it out all-together).
  @autogen_typespec false
  @type! bar() :: integer()
end
iex>t AutogenTypespecsExample # Will show type of `foo` but not `bar`
"@type foo() :: integer()"

TypeCheck.Options 
    



      
Defines the options that TypeCheck supports on calls to use TypeCheck.
Supported options:
	:overrides: A list of overrides for remote types. (default: [])
	:default_overrides: A boolean. If false, will not include any of the overrides of the types of Elixir's standard library (c.f. TypeCheck.DefaultOverrides.default_overrides/0). (default: true)
	:enable_runtime_checks: When true, functions that contain a @spec! will be wrapped with a runtime check which will check the input to and result returned from the function. (Default: true).
	:debug: When true, will (at compile-time) print the generated TypeCheck-checking code. (Default: false)

These options are usually specified as passed to use TypeCheck,
although they may also be passed in direct calls to TypeCheck.conforms/3 (and its variants).
These options are module-specific and are read/used at compile-time.

  
    
  
  Setting different options for different dependencies


Different default options can be set for each of the different dependencies,
by supplying the desired options in the configuration of that dependency under the :type_check key:
config :your_dependency_name, :type_check, [
  enable_runtime_checks: false
  # etc.
]
Note that these values might (by design) be overridden by module-specific options
that might be specified at the location where the dependency calls use TypeCheck.

  
    
  
  The supported options in detail



  
    
  
  Overrides:


The :overrides field contains a list of remote types to be overridden by a replacement.
This is useful to be able to specify TypeCheck-types for types that you do not have control over
(because they are for instance defined in a library that is not itself using TypeCheck).
For obvious reasons, using TypeCheck directly should be preferred over overriding types.
Each of the elements in the :overrides list should be written as {original_type, replacement_type}.
Both of these can take the shape of either&Module.type/arity or the longer form {Module, :type, arity}.
An example:
use TypeCheck, overrides: [
  {&Ecto.Schema.t/0, &MyProject.TypeCheckOverrides.Ecto.Schema.t/0}
]

  
    
  
  Enabling/Disabling runtime checks


By default, runtime checks are enabled.
In the case where the runtime checks turn out to be too slow (for instance, because of working with very large or deeply nested collections) in a particular module,
they can be turned off completely.
It is recommended to:
	Only turn them off after benchmarking has shown that this will make a significant difference.
	Only turn them off in e.g. the production environment, keeping them on in the development and test environments.

An example:
use TypeCheck, enable_runtime_checks: Mix.env() != :prod

  
    
  
  Debugging


Passing the option debug: true will at compile-time print the generated code
for all added @specs, as well as TypeCheck.conforms/3/TypeCheck.conforms?/3/TypeCheck.conforms!/3 calls.

TypeCheck.TypeError exception
    



      
Exception to be returned or raised when a value is not of the expected type.
This exception has two fields:
	:raw, which will contain the problem tuple of the type check failure.
	:message, which will contain a the humanly-readable representation of the raw problem_tuple

:message is constructed from :raw using the TypeCheck.TypeError.DefaultFormatter.
(TODO at some point this might be configured to use your custom formatter instead)

Behaviour to format your own type errors

Transforms types into StreamData generators.
With the exception of wrap_with_gen/2,
methods in this module are
only compiled when the optional dependency
:stream_data is added to your project's dependencies.

TypeCheck.Builtin 
    



      
Contains TypeCheck specifications for all 'built-in' Elixir types.
These are all the types described on the 'Basic Types', 'Literals' and 'Builtin Types' sections of the Elixir 'Typespecs' documentation page.
See TypeCheck.DefaultOverrides for the 'Remote Types' supported by TypeCheck.
Usually you'd want to import this module when you're using TypeCheck.
This is done automatically when calling use TypeCheck.
If necessary, feel free to hide (using import ... except:)
the things you don't need.

  
    
  
  Ommissions


TypeCheck strives to implement all of the syntax and builtin types
which Elixir itself also supports.
Most of them are supported today.
The rest will hopefully be supported in the near future.
For an up-to-date comparison of what types TypeCheck
does and does not support w.r.t. Elixir's builtin typespecs,
see Comparison to Plain Typespecs.

Checks whether the value is any atom.
Returns a problem tuple with the reason :no_match otherwise.

